Cómo lograr un streaming estable: priorización del tráfico en MikroTik

Las pérdidas de frames en la transmisión (dropped frames) a menudo no se deben a un ordenador débil, sino a un canal saturado: alguien en la red está viendo vídeo en 4K o lanza una descarga, y el flujo saliente del stream empieza a competir con el resto del tráfico. En MikroTik esto se resuelve con priorización: el router marca el tráfico del stream y le entrega primero el ancho de banda.

A continuación — un esquema funcional para RouterOS 7: marcado en mangle, árbol de colas (Queue Tree) y verificación. Las configuraciones generales del router están en la guía completa sobre MikroTik, y una visión general de las capacidades — en el artículo MikroTik: ¿qué tipo de router es y por qué resulta conveniente para las pequeñas empresas?.

Datos iniciales

• El equipo desde el que va la transmisión es 192.168.0.100.
• Internet entra por la interfaz pppoe1.
• Velocidad de subida según la tarifa — 50 Mbit/s.

La dirección del equipo debe ser permanente. Fíjela en IP → DHCP Server → Leases (botón Make Static) o configúrala manualmente, de lo contrario tras un reinicio las reglas dejarán de coincidir.

Paso 1. Marcado de conexiones y paquetes

La documentación de MikroTik recomienda primero marcar la conexión y luego los paquetes en ella: comprobar los encabezados de cada paquete es más caro para la CPU que marcar la conexión una sola vez.

/ip firewall mangle
add chain=forward src-address=192.168.0.100 out-interface=pppoe1 \
    connection-state=new action=mark-connection \
    new-connection-mark=stream_conn passthrough=yes comment="stream: conexión"
add chain=forward connection-mark=stream_conn out-interface=pppoe1 \
    action=mark-packet new-packet-mark=stream_up passthrough=no comment="stream: paquetes"

La primera regla marca las conexiones nuevas del equipo con el stream, la segunda pone la marca stream_up en los paquetes salientes de esas conexiones.

Si desde ese equipo no solo sale la transmisión, seleccione el tráfico más precisamente. El RTMP clásico funciona por el puerto TCP 1935; añada en la primera regla protocol=tcp dst-port=1935. Si el programa transmite por RTMPS (puerto 443), el filtro por puerto también capturará HTTPS normal, y entonces es más fiable marcar todo el tráfico del equipo.

Paso 2. Árbol de colas

/queue tree
add name=UP-TOTAL parent=pppoe1 max-limit=45M
add name=UP-STREAM parent=UP-TOTAL packet-mark=stream_up \
    limit-at=8M max-limit=45M priority=1
add name=UP-OTHER parent=UP-TOTAL packet-mark=no-mark \
    limit-at=5M max-limit=45M priority=8

Qué significan los parámetros:

• max-limit de la cola padre — un poco por debajo de la velocidad real del canal, aproximadamente 90 % de la tarifa. La cola debe formarse en MikroTik y no en el equipo del proveedor: solo así el router decide qué paquetes enviar primero.
• limit-at — ancho de banda garantizado. Al stream se le asignan 8 Mbit/s: esto es suficiente para una transmisión 1080p con margen. Sustituya por el bitrate de sus ajustes de OBS más un 20–30 %.
• priority — de 1 (máxima) a 8 (mínima). Según la documentación la prioridad funciona solo entre colas hijas: después de que cada una haya recibido su limit-at, el ancho de banda libre se entrega primero a la cola con mayor prioridad. No funciona sobre la cola padre.
• max-limit de las colas hijas no debe exceder el del padre.
• packet-mark=no-mark — todo el resto del tráfico que no tiene marca.

La suma de los limit-at de las colas hijas no debe exceder el max-limit del padre.

Paso 3. FastTrack

En la configuración estándar de RouterOS está activado FastTrack: acelera el tratamiento de conexiones establecidas, pasándolas por fuera de parte de las cadenas. La documentación advierte explícitamente que ese tráfico evita las colas, y éstas no funcionan.

La forma más simple es excluir las conexiones marcadas de la regla FastTrack. Encuéntrela en IP → Firewall → Filter Rules (acción fasttrack-connection) y añada la condición connection-mark=no-mark:

/ip firewall filter
set [find action=fasttrack-connection] connection-mark=no-mark

Ahora las conexiones del stream siguen la ruta normal y entran en la cola, y el resto del tráfico sigue acelerándose con FastTrack. Si la cola UP-OTHER también debe funcionar, habrá que desactivar FastTrack completamente. Esto aumentará notablemente la carga en la CPU, especialmente en modelos de gama baja.

Paso 4. Verificación

1. Inicie la transmisión y abra Queues → Queue Tree. En la cola UP-STREAM deben aumentar los contadores de bytes y paquetes.

2. Compruebe que las reglas mangle se disparan:

   bash Copy

   /ip firewall mangle print stats where comment~"stream"

3. Cargue el canal: inicie una descarga grande a la nube desde otro dispositivo. En las estadísticas de OBS no debería aparecer pérdida de frames, y en la cola UP-OTHER se verá la limitación.

Errores típicos

• Las colas no funcionan. Con mayor frecuencia el tráfico sale por FastTrack o las marcas no coinciden: verifique los contadores de las reglas mangle.
• max-limit superior a la velocidad del canal. La cola se forma en el proveedor y las prioridades del router no afectan.
• Cola hija con max-limit mayor que la del padre. Esa configuración no da ancho de banda extra y solo complica la configuración.
• Marcada la dirección equivocada. El equipo obtuvo otra dirección por DHCP y las reglas ya no coinciden.
• Configurado solo el tráfico entrante. Para la transmisión es importante el canal saliente: la cola se aplica en la interfaz externa, no en la red local.

Otras herramientas

En RouterOS 7 hay otros tipos de colas, por ejemplo CAKE y FQ-CoDel: reducen la latencia para todo el tráfico a la vez, sin marcado manual. Para una red doméstica es una buena alternativa si se quiere reducir la latencia general al cargar el canal, en lugar de dar prioridad a un solo equipo. Cómo reservar el propio canal de comunicación está tratado en la serie Redundancia de canales de comunicación: Parte 2 — Dentro del edificio: tarjetas de red, switches, bonding y LACP.